1 REM LOESEN EINES LINERAREN GLEICHUNGSYSTEMS MIT HILFE DES HORNER-SCHEMAS
2 :
3 REM GERMANO CARONNI GREUBSTELSTR.10 CH-5430 WETTINGEN TEL.0041/56262574
4 :
10 POKE53280,0:POKE53281,0:PRINT"[147]"
20 INPUT"ANZAHL UNBEKANNTE ";N:IFN<2ORN>10THENPRINT"[145][145]":GOTO20
30 DIMA(N,N),B(N)
40 FORI=1TON:PRINT"ZEILE";I;:FORJ=1TON:PRINTTAB(12);"SPALTE ";J;
50 INPUTA(I,J):NEXTJ
60 PRINTTAB(12);"KONSTANTE ";
70 INPUTA(I,0):NEXTI
80 PRINT
90 :
100 FORI=1TON-1:FL=0:DK=I
102 IFA(I,I)<>0THEN105
103 DK=DK+1:IFDK>NTHENPRINT"TUT MIR LEID, UEBERBESTIMMT !":END
104 FORJ=0TON:A=A(I,J):A(I,J)=A(DK,J):A(DK,J)=A:NEXT:PRINT"*-":GOTO102
105 A=A(I,I)*-1:FORK=ITON:A(I,K)=A(I,K)/A:NEXTK:A(I,0)=A(I,0)/A
110 FORJ=I+1TON
119 IFA(J,I)=0THENPRINT"*+":GOTO140
120 A=A(J,I):FORK=ITON:A(J,K)=A(J,K)/A:NEXTK:A(J,0)=A(J,0)/A
130 FORK=ITON:A(J,K)=A(J,K)+A(I,K):NEXTK:A(J,0)=A(J,0)+A(I,0)
140 NEXTJ,I
145 :
150 FORI=NTO1STEP-1
155 IFA(I,I)=0THENPRINT"DIE GLEICHUNG HAT KEINE EINDEUTIGE LOESUNG":END
160 A(I,0)=A(I,0)/A(I,I):A(I,I)=1:B(I)=A(I,0):PRINTI,B(I):IFI=1THEN180
170 FORJ=1TOI-1:A(J,0)=A(J,0)-A(J,I)*B(I):A(J,I)=0:NEXTJ
180 NEXTI
190 PRINT
199 :
500 FORI=1TON:FORJ=1TON:PRINTA(I,J);"[157]";:NEXTJ:PRINT"=";A(I,0):NEXTI
510 PRINT""
520 INPUT"NAME ";A$:IFA$=""THENEND
530 OPEN2,8,2,"HORN"+STR$(N)+"LOESUNG,S,W":FORI=1TON:PRINT#2,B(I):NEXT:CLOSE2